Как использовать функцию ВПР в Excel -

Резюме

ВПР - это функция Excel для поиска данных в таблице, организованной вертикально. ВПР поддерживает приблизительное и точное соответствие, а также символы подстановки (*?) Для частичных совпадений. Значения поиска должны появиться в первом столбце таблицы, переданной в VLOOKUP.

Цель

Найдите значение в таблице по первому столбцу

Возвращаемое значение

Соответствующее значение из таблицы.

Синтаксис

= ВПР (значение; таблица; индекс_столбца; (поиск_диапазона))

Аргументы

значение - значение, которое нужно искать в первом столбце таблицы.
table - таблица, из которой нужно получить значение.
col_index - столбец в таблице, из которого нужно получить значение.
range_lookup - (необязательно) TRUE = приблизительное совпадение (по умолчанию). FALSE = точное совпадение.

Версия

Excel 2003

Примечания по использованию

ВПР - это функция Excel для получения данных из таблицы, организованной вертикально. Значения поиска должны появиться в первом столбце таблицы, переданной в VLOOKUP. ВПР поддерживает приблизительное и точное соответствие, а также символы подстановки (*?) Для частичных совпадений.

V для вертикального

Цель VLOOKUP - получить информацию из таблицы, организованной следующим образом:

Используя номер заказа в столбце B в качестве значения поиска, функция VLOOKUP может получить идентификатор клиента, сумму, имя и состояние для любого заказа. Например, чтобы получить имя клиента для заказа 1004, формула:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Для горизонтальных данных вы можете использовать HLOOKUP, INDEX и MATCH или XLOOKUP.

ВПР основывается на номерах столбцов

Когда вы используете ВПР, представьте, что каждый столбец в таблице пронумерован, начиная слева. Чтобы получить значение из определенного столбца, укажите соответствующий номер в качестве «индекса столбца». Например, индекс столбца для получения имени ниже равен 2:

Фамилию и адрес электронной почты можно получить в столбцах 3 и 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

ВПР только выглядит правильно

VLOOKUP может смотреть только вправо. Данные, которые вы хотите получить (значения результатов), могут появиться в любом столбце справа от значений поиска:

Если вам нужно найти значения слева, см. ИНДЕКС и ПОИСКПОЗ или XLOOKUP.

Точное и приблизительное соответствие

ВПР имеет два режима сопоставления: точное и приблизительное. Имя аргумента, контролирующего сопоставление, - « range_lookup ». Это имя сбивает с толку, потому что, похоже, оно как-то связано с диапазонами ячеек, такими как A1: A10. Фактически, слово «диапазон» в этом случае относится к «диапазону значений» - когда range_lookup имеет значение ИСТИНА, ВПР будет соответствовать диапазону значений, а не точному значению. Хорошим примером этого является использование функции ВПР для расчета оценок.

Важно понимать, что по умолчанию range_lookup имеет значение ИСТИНА, что означает, что ВПР по умолчанию будет использовать приблизительное соответствие, что может быть опасно. Установите для range_lookup значение FALSE, чтобы обеспечить точное соответствие:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Примечание. Вы также можете указать ноль (0) вместо FALSE для точного совпадения.

Полное совпадение

В большинстве случаев вы, вероятно, захотите использовать ВПР в режиме точного соответствия. Это имеет смысл, когда у вас есть уникальный ключ для использования в качестве значения поиска, например, название фильма в этих данных:

Формула в H6 для поиска года на основе точного соответствия названия фильма:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Примерное совпадение

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.